[gambit-list] [newbie] Unbound variable: compile-file

Christian Jaeger christian at pflanze.mine.nu
Sun Aug 12 06:13:10 EDT 2007


andrew cooke wrote:

> ps also, is it possible to make the parens darker in emacs highlighting? 
> which face is it?  thanks!

I've got the following in my .emacs:

(custom-set-variables
 ;; ...
 '(paren-mode (quote paren) nil (paren))
 '(show-paren-delay 0)
 '(show-paren-mode t nil (paren))
 ;;...
 '(paren-face-match ((((class color)) (:background "#f070ff"))))
 '(paren-face-mismatch ((((class color)) (:foreground "white" :background "red"))))
 '(paren-match ((t (:background "#f070ff"))))
 '(paren-mismatch ((t (:background "red"))))
 '(show-paren-match-face ((((class color)) (:background "#0070ff"))))
 '(show-paren-mismatch-face ((((class color)) (:background "red")))))

but then I have a comment in the file that says that except for the last one they have no effect.

I also have:

;; parenface
;; (from http://foldr.org/~michaelw/log/programming/lisp/lispin von haskell.org)
;;http://www.uncommon-sense.net/interests/programming/parenface.el

;; Add a paren-face to emacs and add support for it to the various lisp modes.
;;
;; Based on some code that Boris Schaefer
;; <http://www.uncommon-sense.net/this-site/contact.html> posted to
;; comp.lang.scheme in message
;; <87hf8g9nw5.fsf at qiwi.uncommon-sense.net>.

(defvar paren-face 'paren-face)

(defface paren-face
    '((((class color))
       (:foreground ;;"dimgray"
        ;;"#c070e0" zu violettlich
        ;;"#a0c0ff" zu hell
        "#80a0ff" ;; yeah  well vielleicht zu schwach
        )))
  "Face for displaying a paren."
  :group 'faces)

(defmacro paren-face-add-support (keywords)
  "Generate a lambda expression for use in a hook."
  `(lambda ()
    (let* ((regexp "(\\|)")
           (match (assoc regexp ,keywords)))
      (unless (eq (cdr match) paren-face)
        (setq ,keywords (append (list (cons regexp paren-face)) ,keywords))))))

;; Keep the compiler quiet.
(eval-when-compile
  (defvar scheme-font-lock-keywords-2 nil)
  (defvar lisp-font-lock-keywords-2 nil))

(add-hook 'scheme-mode-hook           (paren-face-add-support scheme-font-lock-keywords-2))
(add-hook 'lisp-mode-hook             (paren-face-add-support lisp-font-lock-keywords-2))
(add-hook 'emacs-lisp-mode-hook       (paren-face-add-support lisp-font-lock-keywords-2))
(add-hook 'lisp-interaction-mode-hook (paren-face-add-support lisp-font-lock-keywords-2))

(provide 'parenface)

;; /parenface






More information about the Gambit-list mailing list